オンラインゲームのマクロ講座 https://ameblo.jp/makuboh/ オンラインゲームのマクロを１から学びたい方向けの講座です。 ja 近況報告
　具体的には
HPやMP回復中（食べ物や飲み物使用時）に攻撃を受ける
↓
敵情報に攻撃中のアクティブ敵が表示
↓
回復中断して反撃

　「回復中敵情報を監視して表示されたら反撃」を組み込んだまでは良かったのだが、それに伴って複数のプログラムの修正が必要になった。

１）敵を討伐した後、ESCで敵の表示を切る
２）NPCに反復クエスト報告した後、ESCで敵の表示を切る
３）表示を切る→次の敵選択の間、敵のHPが0になったことを確認する関数を呼び出さない

　特に（３）が曲者で、関数を呼び出すと新しい敵にカーソルを合わせてしまうので今までのプログラムの関数を修正することにしました。

>>エンチャ売りもＢＯＴじゃなくて普通のマクロで大分楽に動かせるよ

エンチャ売りマクロ作ってみたいな ]]> https://ameblo.jp/makuboh/entry-10774152076.html Thu, 20 Jan 2011 15:22:46 +0900 はじめに 純粋に技術を試す目的がメインであり、それ以外の目的（サーバーに負荷をかけ続ける行為・掲示板に金銭を対価にマクロを売りつける行為等）は一切関知しません。

　また、当講座で制作したマクロは個人作業の手助けとしての目的にのみ使いましょう。マクロを動かしている間目視でチェックするようにし、大規模オンラインゲームの規約のほとんどに挙げられる『他プレイヤの迷惑行為（横やり、狩場占拠）』に十分気をつけてください。






目次
　はじめに
第一章
　UWSCのダウンロードとインストール方法
　UWSCの基本操作
　はじめての編集
　ループを作る
　はじめての編集 おさらい
第二章
　敵のHPを調べる - 画像を使う
　MOUSEORGとクライアント座標
　PEEKCOLORを使ってみよう
　組み込み - 敵の討伐確認
　敵選択 - メインループにて
第三章
　自分のHP/MPを調べる
　最適な回復アイテム使用タイミング
　表示してみよう - fukidasi
第四章
　マップ上の座標クリック
　障害物チェック
　ハッピータイム
　自分バフ
　アクティブMobの対処
第五章
　おまけ - 個人テリトリー操作
リンク集
　UWSC
　２ちゃんねる
　その他参考サイト
]]> https://ameblo.jp/makuboh/entry-10763657334.html Tue, 11 Jan 2011 20:46:55 +0900 敵選択 - メインループにて
//**初期設定*********************************************//
//攻撃キー
public ATTACK1 = VK_1

//HP回復のタイミング
public hpkaifuku = 7

//MP回復のタイミング
public mpkaifuku = 10

//**プログラム開始***************************************//
//敵のHPのX座標とY座標
public hpx = 190//←パーティーメンバーのHPと誤認識を防止
public hpy = 0

//ウインドウをアクティブ化
public id = GETID("DIVINA Ver. ")
ACW(id, STATUS(id, ST_X), STATUS(id, ST_Y))

//メインループ
count = 1
while 1
//敵選択ループ
while 1
//TABキーを押す
KBD2(VK_TAB)

//0.3秒待つ
sleep(0.3)

//まだ倒していないターゲットが表示されたら抜ける
if hpcheck() = 2 then break
wend

//攻撃ループ
while 1
//攻撃キーを押す
KBD2(ATTACK1)

//敵のHPが0か確認(1秒ごと)
sleep(1)
if hpcheck() = 0 then break
sleep(1)
if hpcheck() = 0 then break
sleep(1)
if hpcheck() = 0 then break
sleep(1)
if hpcheck() = 0 then break
wend

ifb count MOD hpkaifuku = 0 then
//HP回復アイテムを使う
KBD2(VK_6)
sleep(15)
endif

ifb count MOD mpkaifuku = 0 then
//MP回復アイテムを使う
KBD2(VK_7)
sleep(15)
endif

//カウント増加
count = count + 1
wend

//敵のHPチェック
FUNCTION hpcheck()
sw = STATUS(id, ST_WIDTH)
sh = STATUS(id, ST_HEIGHT)

//敵のHPバー認識
ifb CHKIMG("HP.bmp", 1, hpx, hpy, sw, sh) then
hpx = G_IMG_X
hpy = G_IMG_Y
else
//↓プレイヤーがHPバーを動かした時に対応
//座標の初期化
hpx = 190
hpy = 0
//少し待ってTABキー押し直す、関数の再帰呼び出し
sleep(0.3)
KBD2(VK_TAB)
RESULT = hpcheck()
EXIT
endif

//HP最大値、最小値チェック
c = PEEKCOLOR(hpx + 1, hpy + 4)//←指定座標の色を拾う
cr = c and $FF//←R(赤)成分を抽出
ifb cr <= 205 then
RESULT = 1
c = PEEKCOLOR(hpx + 95, hpy + 4)
cr = c and $FF
if cr <= 205 then RESULT = 2
else
RESULT = 0
endif
FEND

//ボタンを押して話す
PROCEDURE KBD2(vk)
KBD(vk,DOWN)
sleep(0.067)
KBD(vk,UP)
FEND


　メインループで敵を選択する部分も「敵選択ループ」としてループさせるよう改良しました。これは画面内に敵が沸いていない時に無意味に攻撃ボタンを押すのを防止するためです。敵を倒す→新しい敵を探す流れを続けていくと敵が居なくなる時もありえるためです。

　これで敵を探して倒すという単純なループを確実に行えるようマクロが組上がりました。
　次の章ではさらに自分のHPやMPを読み取って最適なタイミングでHPやMP回復が行えるようマクロを拡張していきます。 ]]> https://ameblo.jp/makuboh/entry-10765393846.html Tue, 11 Jan 2011 20:39:16 +0900 組み込み - 敵の討伐確認
　第一章の最後に作ったマクロから少し変更しています。まず攻撃ボタンはプレイヤーごとに違うことが多いので、攻撃キーというのを新設しました。ここでは「public ATTACK1 = VK_1」というようにメインの攻撃キーは１キーとして指定しています。

//**初期設定*********************************************//
//攻撃キー
public ATTACK1 = VK_1

//HP回復のタイミング
public hpkaifuku = 7

//MP回復のタイミング
public mpkaifuku = 10

//**プログラム開始***************************************//
//敵のHPのX座標とY座標
public hpx = 190//←パーティーメンバーのHPと誤認識を防止
public hpy = 0

//ウインドウをアクティブ化
public id = GETID("DIVINA Ver. ")
ACW(id, STATUS(id, ST_X), STATUS(id, ST_Y))

//メインループ
count = 1
while 1
//TABキーを押す
KBD2(VK_TAB)

//1秒待つ
sleep(1)

//攻撃ループ
while 1
//攻撃キーを押す
KBD2(ATTACK1)

//しばらく待つ
sleep(4)

//敵のHPが0か確認
if hpcheck() = 0 then break
wend

ifb count MOD hpkaifuku = 0 then
//HP回復アイテムを使う
KBD2(VK_6)
sleep(15)
endif

ifb count MOD mpkaifuku = 0 then
//MP回復アイテムを使う
KBD2(VK_7)
sleep(15)
endif

//カウント増加
count = count + 1
wend

//敵のHPチェック
FUNCTION hpcheck()
sw = STATUS(id, ST_WIDTH)
sh = STATUS(id, ST_HEIGHT)

//敵のHPバー認識
ifb CHKIMG("HP.bmp", 1, hpx, hpy, sw, sh) then
hpx = G_IMG_X
hpy = G_IMG_Y
else
//↓プレイヤーがHPバーを動かした時に対応
//座標の初期化
hpx = 190
hpy = 0
//少し待ってTABキー押し直す、関数の再帰呼び出し
sleep(0.3)
KBD2(VK_TAB)
RESULT = hpcheck()
EXIT
endif

//HP最大値、最小値チェック
c = PEEKCOLOR(hpx + 1, hpy + 4)//←指定座標の色を拾う
cr = c and $FF//←R(赤)成分を抽出
ifb cr <= 205 then
RESULT = 1
c = PEEKCOLOR(hpx + 95, hpy + 4)
cr = c and $FF
if cr <= 205 then RESULT = 2
else
RESULT = 0
endif
FEND

//ボタンを押して話す
PROCEDURE KBD2(vk)
KBD(vk,DOWN)
sleep(0.067)
KBD(vk,UP)
FEND


　敵は攻撃キーを１回押しただけで倒しきれるとは限らないので、攻撃ループというのを設けました。これで敵のHPが0になるまで攻撃しつづけるようになりました。

　もう少し細かく敵のHPが0になるのをチェック出来るようにしてみましょう。

//敵のHPが0か確認(1秒ごと)
sleep(1)
if hpcheck() = 0 then break
sleep(1)
if hpcheck() = 0 then break
sleep(1)
if hpcheck() = 0 then break
sleep(1)
if hpcheck() = 0 then break


　単純に４秒待って敵のHPが0か確認する部分を4つに切り分けただけですが、２ループ目の最初に敵が倒された際３秒余分に待たされることが無い分見た目大分良くなったと思います。 ]]> https://ameblo.jp/makuboh/entry-10765383844.html Tue, 11 Jan 2011 20:24:15 +0900 PEEKCOLORを使ってみよう
　UWSCヘルプのPEEKCOLORの(例)内に以下のプログラムが書かれています。

//　カーソル位置の色を表示
x　=　G_MOUSE_X;　y　=　G_MOUSE_Y
c　=　PeekColor(x,　y)
PRINT　"赤="+G_赤(c)+",緑="+G_緑(c)+",青="+G_青(c)

～中略～

//　以下　関数
function　G_赤(c)
　　Result　=　c　and　$FF
fend
function G_緑(c)
　　Result　=　(c　and　$FF00)　/　$100
fend
function　G_青(c)
　　Result　=　(c　and　$FF0000)　/　$10000
fend


　これを元にして前回のプログラムからPEEKCOLOR以下の文を加えました。また、TABで敵を選択しつづけるよう改良も加えました。

マクロ講座5.UWS
//敵のHPのX座標とY座標
public hpx = 190//←パーティーメンバーのHPと誤認識を防止
public hpy = 0

//ウインドウをアクティブ化
public id = GETID("DIVINA Ver. ")
ACW(id, STATUS(id, ST_X), STATUS(id, ST_Y))
MOUSEORG(id)//←座標をクライアント座標に変更

//少し待つ
sleep(0.3)

//TABキーを押す
KBD2(VK_TAB)

//敵のHPチェック(動作確認)
PRINT hpcheck()

//敵のHPチェック
FUNCTION hpcheck()
sw = STATUS(id, ST_WIDTH)
sh = STATUS(id, ST_HEIGHT)

//敵のHPバー認識
ifb CHKIMG("HP.bmp", 1, hpx, hpy, sw, sh) then
hpx = G_IMG_X
hpy = G_IMG_Y
else
//↓プレイヤーがHPバーを動かした時に対応
//座標の初期化
hpx = 190
hpy = 0
//少し待ってTABキー押し直す、関数の再帰呼び出し
sleep(0.3)
KBD2(VK_TAB)
RESULT = hpcheck()
EXIT
endif

//HP最大値、最小値チェック
c = PEEKCOLOR(hpx + 1, hpy + 4)//←指定座標の色を拾う
cr = c and $FF//←R(赤)成分を抽出
ifb cr <= 205 then
RESULT = 1
c = PEEKCOLOR(hpx + 95, hpy + 4)
cr = c and $FF
if cr <= 205 then RESULT = 2
else
RESULT = 0
endif
FEND

//ボタンを押して話す
PROCEDURE KBD2(vk)
KBD(vk,DOWN)
sleep(0.067)
KBD(vk,UP)
FEND


　R(赤)成分を取り出すのは「c and $FF」というのがわかります。$やandの意味を説明すると、それぞれで2ページ消費することになるのでここではPEEKCOLOR関数で取り出した色からR(赤)成分を取り出すのに「c and $FF」という「おまじない」を使うんだ、と思ってもらえるだけで結構です。

　UWSCのヘルプには関数一覧と使用例のセットが詳しく解説されているので、わからなくなったら辞書のようにチェックする癖を付けるようにしてください。

　プログラムを実行するとほとんどの結果に「2」が表示されると思います。これはHPバーの一番右の部分を調べた結果を返しています。HPが１ミリも減っていない場合右端が赤くなっているため「2」を表示します。

　ほかにHPが少しでも削れている場合右端が黒くなるため「1」が表示され、敵のHPが無くなって黒くなると「0」が表示されます。 ]]> https://ameblo.jp/makuboh/entry-10765366794.html Tue, 11 Jan 2011 20:08:58 +0900 MOUSEORGとクライアント座標
HP.bmpをダウンロード

マクロ講座4.UWS
//敵のHPのX座標とY座標
public hpx = 190//←パーティーメンバーのHPと誤認識を防止
public hpy = 0

//ウインドウをアクティブ化
public id = GETID("DIVINA Ver. ")
ACW(id, STATUS(id, ST_X), STATUS(id, ST_Y))
MOUSEORG(id)//←座標をクライアント座標に変更

//少し待つ
sleep(0.3)

//TABキーを押す
KBD2(VK_TAB)

//敵のHPバー認識(動作確認)
PRINT hpcheck()

//敵のHPチェック
FUNCTION hpcheck()
sw = STATUS(id, ST_WIDTH)
sh = STATUS(id, ST_HEIGHT)

//敵のHPバー認識
ifb CHKIMG("HP.bmp", 1, hpx, hpy, sw, sh) then
hpx = G_IMG_X
hpy = G_IMG_Y
MMV(hpx, hpy)
RESULT = "HPバー認識しました"
else
RESULT = "HPバー認識に失敗しました"
endif
FEND

//ボタンを押して話す
PROCEDURE KBD2(vk)
KBD(vk,DOWN)
sleep(0.067)
KBD(vk,UP)
FEND


　上のプログラムについて一つづつ解説します。

　2～3行目：敵のHPのX座標とY座標
　敵のHPバーそれぞれの座標をpublicという接頭辞を付けて初期化しています。publicを付けると下のFUNCTIONやPROCEDURE（関数）内で同じ変数を流用できます。意識せずプログラム内のさまざまな場所で変数の中身を取り出せるメリットがありますが、多様しすぎると名前を思い出せなかったり、プログラムの全体が把握しにくくなるデメリットがあることも気をつけてください。

　8行目：MOUSEORG関数（ここでは座標をid(ゲームウインドウ)内のクライアント座標に変更）
　今回学ぶCHKIMG関数、次回のPEEKCOLOR関数両方で使用するための座標をクライアント基準に変更する関数です。このMOUSEORGという「おまじない」を使うまでは、マウスの座標はグローバル（デスクトップ）を基準にして読み込まれます。関数を使った後はゲームウインドウ内の座標が基準になります。

　クライアント座標というのはゲームアプリ（ゲームクライアント）内の座標という意味です。ゲームウインドウを上部のバーをつまんで上下左右に動かしても中の座標が変わらないので今後のマクロ作りが楽になる、というメリットを受けるためにこの「おまじない」を使います。

　20行目：FUNCTION
　下(36行目)にPROCEDUREというのがありますが、これを単純にFUNCTIONに置き換えたもの、と理解してもらえれば大丈夫です。FUNCTIONは必ずRESULT = "結果"の行を付け加えなければエラーを起こします。ボタンを操作するだけの場合は結果を求める必要がないので付け加える必要はありませんが、ここでは結果を最後に表示するために使用します。

　28行目：MMV
　マウスを指定した座標に移します。ここではHP.bmpでHPバーを認識した後、画像認識の開始座標（左上）にマウスカーソルを動かすという意味です。

　17行目：PRINT
　UWSCが勝手に一つウインドウを開いて結果をウインドウ内に表示するものです。

　プログラムを実行するとウインドウが一つ開いて「HPバー認識しました」「HPバー認識に失敗しました」のいずれかの結果が出てくると思います。失敗メッセージが出る場合はTABキーかF1キーを押してHPバーを画面上に表示させてください。また、HPバーが左端に置いている場合もエラーが出ますので、左端以外の場所に動かしてください。 ]]> https://ameblo.jp/makuboh/entry-10765167974.html Tue, 11 Jan 2011 16:53:54 +0900 敵のHPを調べる - 画像を使う
　まずは画像を作成します。まずはゲーム画面をALT+PrintScreenキーでクリップボードに取り込みます。

画像：取り込まれたゲーム画面

　これをペイントに貼りつけ（ペースト）し、指定の部分を拡大や画面の大きさを変更しながら切りだしていきます。ここでは敵のHPを調べるために右上の一部分を切り出します。

画像：切り出された部分

　さらに、バケツツールを使い背景とかぶっている部分を適当な色で覆い隠し、完成形の画像へ持っていきます。

　ここからは「別名で保存」でHP.bmpという名前で扱っています。

HP.bmpをダウンロード

　次は実際にこの画像を使ってマクロを作っていきます。 ]]> https://ameblo.jp/makuboh/entry-10764726900.html Tue, 11 Jan 2011 01:24:44 +0900 はじめての編集 おさらい
マクロ講座3.UWS
//HP回復のタイミング
hpkaifuku = 7

//MP回復のタイミング
mpkaifuku = 10

//ウインドウをアクティブ化
public id = GETID("DIVINA Ver. ")
ACW(id, STATUS(id, ST_X), STATUS(id, ST_Y))

//メインループ
count = 1
while 1
//TABキーを押す
KBD2(VK_TAB)

//1秒待つ
sleep(1)

//1キーを押す
KBD2(VK_1)

//しばらく待つ
sleep(4)

ifb count MOD hpkaifuku = 0 then
//HP回復アイテムを使う
KBD2(VK_6)
sleep(15)
endif

ifb count MOD mpkaifuku = 0 then
//MP回復アイテムを使う
KBD2(VK_7)
sleep(15)
endif

//カウント増加
count = count + 1
wend

//ボタンを押して離す
PROCEDURE KBD2(vk)
KBD(vk,DOWN)
sleep(0.067)
KBD(vk,UP)
FEND


　hpkaifuku, mpkaifuku, countという名前とifb～endifというものが加わりました。それぞれを解説していきます。

　hpkaifuku, mpkaifuku, countというのは変数といって中に自由に内容を入れたり出したりできます。数学でいうxやyというのがそれに当たります。このプログラムでは最初にhpkaifuku, mpkaifukuという名前でプログラムをテキストエディタで開いて内容を自由に選べるようにしています。

　countというのは下のメインループが何回続いたか記録する変数です。forループでは一定の数を数えた後ループを抜けるようになるので、永遠と続かせるためにwhileループを使用しています。

　「ifb count MOD hpkaifuku = 0 then」という聞きなれない行が出ています。意味はcountがHP回復のタイミングで割り切れる数というものです。ここではhpkaifukuに7が入っているので、count MOD 7 = 0と同じ意味になります。countが7で割り切れる、つまり7や7の倍数のときのみifb～endifで囲まれた行を実行することになります。

　意味がさっぱり分からないという人は、しばらく攻撃したらHPやMP回復アイテムを使う便利な機能がここで組み込まれている、程度に理解してもらえば大丈夫です。 ]]> https://ameblo.jp/makuboh/entry-10763824961.html Mon, 10 Jan 2011 09:56:38 +0900 ループを作る
マクロ講座2.UWS
//ウインドウをアクティブ化
public id = GETID("DIVINA Ver. ")
ACW(id, STATUS(id, ST_X), STATUS(id, ST_Y))

//攻撃ループ
while 1
//TABキーを押す
KBD2(VK_TAB)

//1秒待つ
sleep(1)

//1キーを押す
KBD2(VK_1)

//しばらく待つ
sleep(4)
wend

//ボタンを押して離す
PROCEDURE KBD2(vk)
KBD(vk,DOWN)
sleep(0.067)
KBD(vk,UP)
FEND


　前回のプログラムに加えてキーを押した動作の後しばらく待つのを加えました。他にもTABキーを押してから最後の部分までwhile～wendで囲みました。

　while 1というのは常にこのループを続けるという意味です。プログラムを終了するにはUWSC側の停止ボタンを押します。

～停止ボタン～

　このままではキャラクターのHPが0になるまでひたすら攻撃するだけなので途中にHP回復を挟みます。

マクロ講座2-2.UWS
//ウインドウをアクティブ化
public id = GETID("DIVINA Ver. ")
ACW(id, STATUS(id, ST_X), STATUS(id, ST_Y))

//メインループ
while 1
//攻撃ループ
for i = 1 to 7
//TABキーを押す
KBD2(VK_TAB)

//1秒待つ
sleep(1)

//1キーを押す
KBD2(VK_1)

//しばらく待つ
sleep(4)
next

//回復アイテムを使う
KBD2(VK_6)
sleep(15)
wend

//ボタンを押して離す
PROCEDURE KBD2(vk)
KBD(vk,DOWN)
sleep(0.067)
KBD(vk,UP)
FEND


　whileのほかにfor～nextというのが増えましたが、これもループの一つで1から7の7回攻撃ループを続けるという意味です。この後のスクリプトは以上の「メインループ」を軸に拡張していきます。

　ほとんどのゲームプログラムはキャラクターや背景が動いたりHPやMPが上下したりする一連の動作を「メインループ」内で行っています。マクロも主な動作はそれにならってメインループ内でやり取りするのが理解しやすいです。 ]]> https://ameblo.jp/makuboh/entry-10763811456.html Mon, 10 Jan 2011 09:41:06 +0900 はじめての編集
～スクリプト～

　再生してみるとボタンを押したのに動作しない場合があります。これはPCゲームによくある「ボタンを押した状態をゲームが受け付ける」時間が一定の時間必要なため、押した状態を手続きすることにします。

　ついでにACWの部分も変更します。

マクロ講座1.UWS
//ウインドウをアクティブ化
public id = GETID("DIVINA Ver. ")
ACW(id, STATUS(id, ST_X), STATUS(id, ST_Y))

//TABキーを押す
KBD2(VK_TAB)

//1秒待つ
sleep(1)

//1キーを押す
KBD2(VK_1)

//ボタンを押して離す
PROCEDURE KBD2(vk)
KBD(vk,DOWN)
sleep(0.067)
KBD(vk,UP)
FEND


　ボタンを押して話す行動を手続きしてそれぞれの場所で呼び出します。一般的なプログラム言語では関数と呼ばれるものですが、今は読み込みして動くことだけ確認出来れば大丈夫です。

　スクリプトの書き方が間違っている場合、どこどこの行が間違っているという警告をUWSCが出すのでスクリプトの編集はメモ帳以外の行番号のわかるテキストエディタを使うようにしましょう。

～警告メッセージ～

この場合どこどこの行の書き方が間違っているのがわかります。 ]]> https://ameblo.jp/makuboh/entry-10763800704.html Mon, 10 Jan 2011 09:20:38 +0900